COBOL（コボル）言語の予約語「START」を使用したファイルの読み出し位置の指定とは

START（英語）は、日本語に訳すると「出発する」、「歩き出す」、「動き始める」、「始まる」、「起こる」などという意味です。

COBOL（コボル）言語のSTART文には、相対編成ファイルや索引順編成ファイルをシーケンシャルに読み出す前に、読み出し開始位置を指定する機能があります。

START文の形式：START～END-START.

START文は、手続き部に記述します。

■書式

　START　ファイル名　KEY　比較演算子　データ名

　　　　INVALID　KEY　無条件文1

　　　　NOT　INVALID　KEY　無条件文2

　END-START.

■構文規則

＜ファイル名＞

読み出し開始位置を決めるファイル名を記述します。

＜比較演算子＞

「IS」で始まる比較演算子を記述します。

比較演算子の詳細は、「START文のCOBOL(コボル)言語における基本事項やルールについて」を参照してください。

＜データ名＞

比較演算子で比較対象とするデータ名を記述します。

＜無条件文1＞

「KEY　比較演算子　データ名」で、条件に該当するキーがなかった場合に実行する命令群を記述します。

＜無条件文2＞

「KEY　比較演算子　データ名」で、条件に該当するキーがあった場合に実行する命令群を記述します。

■使用例

START文で読み出し開始位置を設定し、ファイルをシーケンシャルに読み出すプログラム例をご紹介します。

以下のプログラム例では、コンソールからレコードキーの値を入力し、索引順編成ファイル「SEIHIN」を入力されたキー値以降のレコードを読み出し表示しています。

■索引順編成ファイル「SEIHIN」のレコード様式とレコード内容

索引順編成ファイル「SEIHIN」は、3桁の製品コード（キー）の昇順に並び、「001」～「005」までが登録されています。

　　レコード1：001りんご 0300

　　レコード2：002めろん 1000

　　レコード3：003みかん 0200

　　レコード4：004ばなな 0180

　　レコード5：005いちご 0800

■実行結果

はじめに製品コードの入力を促すメッセージが表示されます。

数字の0を入力してみます。

エラーメッセージが表示され、プログラムが終了しました。

もう一度、プログラムを実行し、今度は数字の1を入力してみます。

製品コード「001」以下のレコードが全て表示され、プログラムが終了しました。

もう1度、プログラムを実行し、今度は数字の3を入力してみます。

製品コード「003」以下のレコードが全て表示され、プログラムが終了しました。

COBOL言語において、START文は、ファイルの読み出し位置を定めるために、または明示的にトランザクションを開始するために使用します。トランザクション処理については、別の機会に説明しますので、ここでは「ファイルの読み出し位置を定める」に限って解説します。

START文に指定する比較演算子は、基本的にIF（判断）文、EVALUATE（評価）文などと同じです。表1にSTART文に指定できる比較演算子と、比較演算子の意味をご紹介します。

　　　表1　START文に指定できる比較演算子と比較演算子の意味

START文で読み出し位置を指定できるのは、索引順編成ファイルと相対ファイルです。ランダム編成ファイルや順編成ファイルには指定できません。

START文で読み出し開始位置を指定する前に、ファイルをオープンする必要があります。読み出し位置を指定し、ファイルを読み込む場合は、OPEN、START、READ、CLOSEの順に命令を記述してください。

実務で稼働するCOBOLプログラムでは、一度、読み出し位置を指定して処理を行ったあとに、何かの条件で、また違う位置から読み出す必要があることもあります。

START文を使用すると、ファイルのOPENからCLOSEの間に、何度でも読み出し位置を変更（指定）することができます。

では、「COBOL(コボル)言語のSTART文とは？」でご紹介したプログラム例をベースに、ファイルの内容を表示するだけではなく、内容を変更し、最後にファイルの先頭から変更後の内容を表示するプログラムを作成してみましょう。

「COBOL(コボル)言語のSTART文とは？」でご紹介したプログラム例からの変更箇所は、赤のマーカー部分です。

******************************************************************
* Author:
* Date:
* Purpose:
* Tectonics: cobc
******************************************************************
IDENTIFICATION DIVISION.
PROGRAM-ID. START_SAMPLE2.
 
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
  SELECT IN-FILE ASSIGN TO "SEIHIN1"
          ACCESS MODE IS SEQUENTIAL
          ORGANIZATION IS INDEXED
          RECORD KEY IS IN-CODE.
 
DATA DIVISION.
FILE SECTION.
FD  IN-FILE.
01  IN-REC.
  03  IN-CODE     PIC 9(03).
  03  IN-HINMEI   PIC X(10).
  03  IN-KAKAKU   PIC 9(04).
 
WORKING-STORAGE SECTION.
01  WORKING-AREA.
  03  END-FLG     PIC X(03).
  03  CNSL-INPUT  PIC 9(01).
  03  CNSL-KAKAKU PIC 9(04).
 
*-------------------------------------------
*　主手続
*-------------------------------------------
PROCEDURE DIVISION.
 
MAIN-PROCEDURE.
*  メッセージ表示＆入力
  MOVE ZERO TO CNSL-INPUT.
  DISPLAY "製品コード（0-9）を入力してください".
  ACCEPT CNSL-INPUT FROM CONSOLE.
 
*  ファイルオープン
  OPEN I-O IN-FILE.
 
*  読み出し位置の指定
  MOVE CNSL-INPUT TO IN-CODE.
  START IN-FILE KEY IS EQUAL TO IN-CODE
    INVALID KEY
      DISPLAY "入力された番号のレコードが存在しません"
      GO TO END-PROC
    NOT INVALID KEY
      CONTINUE
    END-START.
 
*  レコード読み出し
  MOVE SPACE TO END-FLG.
  PERFORM UNTIL END-FLG = "END"
    READ IN-FILE
      AT END
        MOVE "END" TO END-FLG
      NOT AT END
        DISPLAY IN-REC
        DISPLAY "価格を入力してください"
        ACCEPT CNSL-KAKAKU FROM CONSOLE
        MOVE CNSL-KAKAKU TO IN-KAKAKU
        REWRITE IN-REC
    END-READ
  END-PERFORM.
 
*  ファイル内容の表示（読み出し位置を始めに戻す）
  MOVE 1 TO IN-CODE.
  START IN-FILE KEY IS EQUAL TO IN-CODE
    INVALID KEY
      DISPLAY "指定した番号のレコードが存在しません"
      GO TO END-PROC
    NOT INVALID KEY
      CONTINUE
  END-START.
 
*  ファイル内容の表示（レコード読み出しと表示）
  MOVE SPACE TO END-FLG.
  PERFORM UNTIL END-FLG = "END"
    READ IN-FILE
      AT END
        MOVE "END" TO END-FLG
      NOT AT END
        DISPLAY IN-REC
    END-READ
  END-PERFORM.
 
*終了処理
END-PROC.
  CLOSE IN-FILE.
  STOP RUN.
END PROGRAM START_SAMPLE2.

■実行結果

はじめに製品コードの入力を促すメッセージが表示されます。

数字の4を入力してみます。

製品コード「004」のレコードが表示され、価格の入力が促されました。

250を入力します。

製品コード「005」のレコードが表示され、価格の入力が促されました。

800を入力します。

変更後のファイルの内容が表示され、プログラムが終了しました。

START文による、ファイルの読み出し位置指定は、実務でもよく使用されるCOBOLプログラムの基本的なテクニックです。ぜひ、使い方を覚えておきましょう。

• 前の記事へ
• 次の記事へ

この記事を読んだ人は、こちらの記事も読んでいます

【未経験者歓迎】COBOLプログラマー・システムエンジニアの募集

株式会社COBOLの求人・転職・募集情報を見る

COBOL入門のカテゴリー

｜　基礎　｜　応用　｜　勉強　｜　試験　｜　辞書　｜