徹底解説！一歩先を行くCOBOL言語のデータ共有｜応用ガイド

COBOL(コボル)言語でデータを共有するEXTERNAL句を使った命令文の書き方とは

応用-external-イメージ1

COBOL(コボル)言語のデータ共有とは？

COBOL(コボル)において、異なるプログラム間でデータを共有するには、レコードに外部属性を与えるEXTERNAL句を使用します。

EXTERNAL句を指定したデータ項目や集団項目は、プログラムの実行単位中のレコードデータを記述する全てのプログラム間でデータを共有できます。
応用-external-イメージ2

COBOL(コボル)言語における共有データの定義

共有データを定義するには、作業場所節（WORKING-STORAGE SECTION）又はファイル記述項（FILE SECTION）に記述します。

書き方1:共有データ
DATA DIVISION.
WORKING-STORAGE SECTION.
　01 データ項目 IS EXTERNAL.

書き方2：共有ファイル
FILE SECTION.
　FD ファイル項目 IS EXTERNAL.

規則や注意点：
・EXTERNAL句はレベル番号01のデータ記述項及び、ファイル記述項のFD句のみ指定することができます。
・1つの実行単位の中で複数のプログラムが同じデータを共有する場合は、関連するレコード記述項の各レコード名は同じ名前で定義する必要があります。
・EXTERNAL句を指定したデータ項目は、同じプログラムで別のレベル番号01で指定したデータ項目名と重複することはできません。
・EXTERNAL句を指定した項目やその配下の基本項目にVALUE句を指定することはできません。

データを共有するEXTERNAL句の応用的な使い方

ここではEXTERNAL句を使用して、データ項目を共有する方法について見ていきましょう。
以下の3つのプログラムを作成し、外部プロブラムからデータの共有（参照、変更）ができることを確認します。

サンプルプログラム
SHARE_PG01.cob

 IDENTIFICATION       DIVISION.
 PROGRAM-ID.          SHARE_PG01.
 ENVIRONMENT          DIVISION.
 CONFIGURATION        SECTION.
 
 DATA                 DIVISION. 
 WORKING-STORAGE      SECTION.
 
*>----------------------------------------------------
*> 外部属性を持つデータ項目を定義
*>----------------------------------------------------
   01 WORK-ITEM IS EXTERNAL.
     03 WORK-DATA     PIC X(50).
 
 PROCEDURE            DIVISION.
 MAIN                 SECTION.
 
*>共有データの設定
    MOVE "This is a test of data sharing." TO WORK-DATA.
 
*>----------------------------------------------------
*> 外部プロブラムの呼出し
*>----------------------------------------------------
   CALL "SHARE_PG01-1".
   CALL "SHARE_PG01-2".
 
   DISPLAY "SHARE_PG01：" WORK-DATA.
 
   STOP RUN.

SHARE_PG01-1.cob

 IDENTIFICATION       DIVISION.
 PROGRAM-ID.          SHARE_PG01-1.
 ENVIRONMENT          DIVISION.
 CONFIGURATION        SECTION.
 
 DATA                 DIVISION.
 WORKING-STORAGE      SECTION.
 
*>----------------------------------------------------
*> 外部属性を持つデータ項目を定義
*>----------------------------------------------------
   01 WORK-ITEM IS EXTERNAL.
     03 WORK-DATA     PIC X(50).
 
 PROCEDURE            DIVISION.
 
   DISPLAY "SHARE_PG01-1："WORK-DATA.
 
   GOBACK.
 
 EXIT PROGRAM.

SHARE_PG01-2.cob

 IDENTIFICATION       DIVISION.
 PROGRAM-ID.          SHARE_PG01-2.
 ENVIRONMENT          DIVISION.
 CONFIGURATION        SECTION.
 
 DATA                 DIVISION.
 WORKING-STORAGE      SECTION.
 
*>----------------------------------------------------
*> 外部属性を持つデータ項目を定義
*>----------------------------------------------------
   01 WORK-ITEM IS EXTERNAL.
     03 WORK-DATA    PIC X(50).
 
 PROCEDURE            DIVISION.
 
   DISPLAY "SHARE_PG01-2：" WORK-DATA.
 
*>共有データの変更
   MOVE "Change shared data." TO WORK-DATA.
 
   GOBACK.
 
 EXIT PROGRAM.